メディア芸術データベース LOD (Deprecated)

2021/01/25 メディア芸術データベース(ベータ版)のLODデータセットが公式に公開されました。

公式のデータセットのSPARQLエンドポイントは以下のページで提供しています。

• メディア芸術データベース SPARQLエンドポイント

本ページは非公式に生成した古いデータセットですので、ご注意ください。

メディア芸術データベース (ベータ版)が試験的に公開しているWeb APIから取得したデータを RDF へ変換して作成したデータセットです。

• 変換スクリプト
• RDF データダンプ

以下は2020/01/16時点で取得したデータを提供しています。

Query with SPARQL

Endpoint: https://sparql.metadata.moe/madb-20200116/query

Examples

• ▶ 公開年毎にTVアニメ数を集計する

  PREFIX schema: <http://schema.org/>
  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX ma: <https://metadata.moe/ns/madb/ma#>
  SELECT ?y (COUNT(DISTINCT *) AS ?cnt)  WHERE {
    ?s a ma:Collection ;
       ma:media "TVレギュラー" ;
       schema:startDate ?startDate .
  }
  GROUP BY (SUBSTR(?startDate, 1, 4) AS ?y)
  ORDER BY DESC(?y)

• ▶ タイトルに「!」「?」を多く含むTVアニメを取得する

  PREFIX schema: <http://schema.org/>
  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX ma: <https://metadata.moe/ns/madb/ma#>
  SELECT ?s ?name ?mark WHERE {
    ?s a ma:Collection ;
       ma:media "TVレギュラー" ;
       schema:name ?name .
    FILTER(LANG(?name) = "")
    FILTER (REGEX(?name, "[!！\\?？]+"))
    BIND (REPLACE(?name, "[^!！\\?？]*([!！\\?？]+)[^!！\\?？]*", "$1") AS ?mark)
  }
  ORDER BY DESC(STRLEN(?mark))
  LIMIT 100

• ▶ 岡田麿里さん参加作品を取得する

  PREFIX schema: <http://schema.org/>
  PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  PREFIX ma: <https://metadata.moe/ns/madb/ma#>
  
  SELECT
  	?col ?colName (GROUP_CONCAT(DISTINCT ?role) AS ?roles)
  WHERE {
    ?col a ma:Collection ;
           ma:media ?media ;
           schema:name ?colName ;
           ^schema:isPartOf ?item .
    VALUES ?media {"TVレギュラー" "劇場上映" "TVスペシャル"}
    {
    	?col schema:contributor ?contributers .
    } UNION {
      ?item schema:contributor ?contributers .
    }
    FILTER(LANG(?colName) = "")
    FILTER(REGEX(?contributers, "岡田\\s*麿里"))
    BIND(REPLACE(?contributers, ".*\\[(.+?)\\]岡田\\s*麿里.*", "$1") AS ?role)
  }
  GROUP BY ?col ?colName

ご利用にあたって

• 本データセットは、文化庁「メディア芸術データベース（ベータ版）」を加工して作成したものです。
• 
  本データセットは、クリエイティブ・コモンズ 表示 4.0 国際 ライセンスの下に提供されています。メディア芸術データベース 利用規約も併せてお読みください。
• 本データセットは、個人が独自に提供しているものですので、文化庁にお問い合わせされないようご注意ください。連絡先はこちらか、内容に応じてGitHub の issueにお願いします。