メディア芸術データベース SPARQLエンドポイント (Unofficial)

メディア芸術データベース(ベータ版)のLODデータセット¹のSPARQLエンドポイントです。

Notice

「メディア芸術データベース・ラボ (MADB Lab)」でSPARQLエンドポイントが提供されるようになったため、お役御免となりました。本エンドポイントは既存利用者のためにしばらく公開は続けますが、今後はMADB Labの利用を推奨します。

Note

過去にこちらのページで提供していた独自のデータセットはメディア芸術データベース LOD (Deprecated)に移動しました。

Query with SPARQL

Endpoint: https://sparql.metadata.moe/madb/query (2022/06/15版)

Examples

PREFIX schema: <https://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX class: <https://mediaarts-db.bunka.go.jp/data/class#>

SELECT ?y (COUNT(DISTINCT *) AS ?cnt)  WHERE {
  ?s a class:AnimationTVRegularSeries ;
     schema:datePublished ?datePublished .
}
GROUP BY (SUBSTR(?datePublished, 1, 4) AS ?y)
ORDER BY DESC(?y)

PREFIX schema: <https://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX class: <https://mediaarts-db.bunka.go.jp/data/class#>

SELECT ?s ?name ?mark WHERE {
  ?s a class:AnimationTVRegularSeries ;
     rdfs:label ?name .
  FILTER(LANG(?name) = "")
  FILTER (REGEX(?name, "[!！\\?？]+"))
  BIND (REPLACE(?name, "[^!！\\?？]*([!！\\?？]+)[^!！\\?？]*", "$1") AS ?mark)
}
ORDER BY DESC(STRLEN(?mark))
LIMIT 100

PREFIX schema: <https://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX class: <https://mediaarts-db.bunka.go.jp/data/class#>

SELECT
 ?col ?colName (GROUP_CONCAT(DISTINCT ?role) AS ?roles)
WHERE {
  ?col a ?class ;
         schema:genre ?genre ;
         rdfs:label ?colName ;
         ^schema:isPartOf ?item .
  VALUES ?class {class:AnimationTVRegularSeries class:AnimationTVSpecialSeries class:AnimationMovieSeries}
  {
   ?col schema:contributor ?contributers .
  } UNION {
    ?item schema:contributor ?contributers .
  }
  FILTER(LANG(?colName) = "")
  FILTER(REGEX(?contributers, "岡田\\s*麿里"))
  BIND(REPLACE(?contributers, ".*\\[(.+?)\\]岡田\\s*麿里.*", "$1") AS ?role)
}
GROUP BY ?col ?colName

PREFIX schema: <https://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX class: <https://mediaarts-db.bunka.go.jp/data/class/>

# 情報資源分類
# Ref. <https://github.com/mediaarts-db/dataset/blob/ea0d43b555f412b127bb2e8127b7469d6e42fa29/README.md#211-%E6%83%85%E5%A0%B1%E8%B3%87%E6%BA%90%E5%88%86%E9%A1%9E>
SELECT
 DISTINCT (?additionalType AS ?分野) (?class AS ?大分類) (?genre AS ?小分類)
WHERE {
  ?col a ?class;
     schema:additionalType ?additionalType ;
         schema:genre ?genre .
}

ご利用にあたって

本サービスは、文化庁「メディア芸術データベース（ベータ版）」が公開しているデータセットを利用しています。データセットの内容は改変しておりません(SPARQLサーバやクライアントソフトウェアの制約に起因する場合は、この限りではありません)。
データセットの利用に当たっては、メディア芸術データベース利用規約も併せてお読みください。
本サービスは、個人が独自に提供しているものですので、文化庁にお問い合わせされないようご注意ください。連絡はこちらにお願いします。

https://github.com/mediaarts-db/dataset ↩︎