ISDN Linked Data

ISDN (International Standard Dojin Numbering; 国際標準同人誌番号) のRDFデータを提供するSPARQLエンドポイントです。

データセット生成については以下リポジトリをご覧ください。

なお、Linked “Open” Data ではないことにご留意ください。

データ更新日: 2026-01-13

Endpoint: https://sparql.metadata.moe/isdn/query

クエリエディタ

サンプルクエリ

PREFIX isdn: <http://metadata.moe/ns/isdn/>
PREFIX schema: <http://schema.org/>

DESCRIBE ?s
{
  ?s isdn:isdn "2784663011044" .
}
PREFIX isdn: <http://metadata.moe/ns/isdn/>
PREFIX schema: <http://schema.org/>

SELECT *
{
  ?s schema:publisher/schema:name "ばびぶべぼ研究室" ;
     schema:name ?name ;
     schema:datePublished ?datePublished .
}
ORDER BY DESC(?datePublished)
PREFIX isdn: <http://metadata.moe/ns/isdn/>
PREFIX schema: <http://schema.org/>

SELECT ?isdnRegistrant ?publisherName (SUM(?numberOfPages) AS ?sumPages)
{
  ?s schema:numberOfPages ?numberOfPages ;
     schema:publisher [
      isdn:isdnRegistrant ?isdnRegistrant ;
      schema:name ?publisherName ;
     ] .
}
GROUP BY ?isdnRegistrant ?publisherName
ORDER BY DESC(?sumPages)
LIMIT 100
PREFIX isdn: <http://metadata.moe/ns/isdn/>
PREFIX schema: <http://schema.org/>

SELECT ?ratingAge (COUNT(*) AS ?cnt)
# SPARQL非標準ですが、Apache Jena独自のデフォルトグラフURIが利用できます
FROM <urn:x-arq:DefaultGraph>
FROM <http://isdn.metadata.moe/graph/ageRestricted15>
FROM <http://isdn.metadata.moe/graph/ageRestricted18>
{
  ?s a isdn:DoujinProduct ;
     isdn:ratingAge ?ratingAge .
}
GROUP BY ?ratingAge
PREFIX isdn: <http://metadata.moe/ns/isdn/>
PREFIX schema: <http://schema.org/>

SELECT ?comicketGenreName (COUNT(DISTINCT ?s) AS ?count)
FROM <urn:x-arq:DefaultGraph>
FROM <http://isdn.metadata.moe/graph/ageRestricted15>
FROM <http://isdn.metadata.moe/graph/ageRestricted18>
{
  ?s schema:genre [
    a isdn:ComiketGenre ;
    schema:name ?comicketGenreName ;
  ]
}
GROUP BY ?comicketGenreName
ORDER BY DESC(?count)
PREFIX isdn: <http://metadata.moe/ns/isdn/>
PREFIX schema: <http://schema.org/>

SELECT ?comicketGenreName ?ratingGender ?ratingAge (COUNT(*) AS ?count)
FROM <urn:x-arq:DefaultGraph>
FROM <http://isdn.metadata.moe/graph/ageRestricted15>
FROM <http://isdn.metadata.moe/graph/ageRestricted18>
WHERE {
  ?work schema:genre [
          a isdn:ComiketGenre ;
          schema:name ?comicketGenreName ;
        ] ;
        isdn:ratingGender ?ratingGender ;
        isdn:ratingAge ?ratingAge .
}
GROUP BY ?comicketGenreName ?ratingGender ?ratingAge
ORDER BY DESC(?count)
PREFIX isdn: <http://metadata.moe/ns/isdn/>
PREFIX schema: <http://schema.org/>

SELECT ?category (COUNT(DISTINCT ?s) AS ?count)
FROM <urn:x-arq:DefaultGraph>
FROM <http://isdn.metadata.moe/graph/ageRestricted15>
FROM <http://isdn.metadata.moe/graph/ageRestricted18>
{
  ?s schema:category ?category
}
GROUP BY ?category
ORDER BY DESC(?count)

グラフURI一覧

年齢制限のあるコンテンツに関しては、グラフURIを分けています。

語彙・制約記述

リソースURI

http://isdn.metadata.moe/res/{isdn}

HTTPで参照すると、コンテンツネゴシエーションでリダイレクトされます。