gBizINFO LOD

経済産業省「gBizINFO」でかつて¹提供されていたSPARQL API バージョン 1.4と同等²のデータを提供するSPARQLエンドポイントです。

データセット生成については以下リポジトリをご覧ください。

• Babibubebon/gbizinfo-lod: CSV to RDF変換ツール
• Babibubebon/gbizinfo-lod-dataset: 生成したデータセット(週1更新)

データ更新日: 2024-06-18

Endpoint: https://sparql.metadata.moe/gbizinfo/query

クエリエディタ

全文検索

API仕様書「7 フルテキスト検索」に相当する ic:表記 プロパティに対する全文検索をサポートしています。

ただし、本エンドポイントではJena Full Text Searchを利用しているため、全文検索に用いる構文が異なります。

PREFIX hj: <http://hojin-info.go.jp/ns/domain/biz/1#>
PREFIX ic: <http://imi.go.jp/ns/core/rdf#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX text: <http://jena.apache.org/text#>

SELECT DISTINCT ?corporateID ?corporateName ?location
{
  GRAPH <http://hojin-info.go.jp/graph/hojin> {
    (?key ?score) text:query (ic:表記 '"日立製作所"' 100) .

    ?s ic:ID/ic:識別値 ?corporateID ;
       ic:名称 ?key ;
       ic:住所/ic:表記 ?location .
    ?key ic:表記 ?corporateName .
  }
}
ORDER BY DESC(?score)

PREFIX hj: <http://hojin-info.go.jp/ns/domain/biz/1#>
PREFIX ic: <http://imi.go.jp/ns/core/rdf#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX text: <http://jena.apache.org/text#>

SELECT DISTINCT ?corporateID ?corporateName ?location
{
  GRAPH <http://hojin-info.go.jp/graph/hojin> {
    (?key ?score) text:query (ic:表記 '"東京都千代田区"' 1000) .

    ?s ic:ID/ic:識別値 ?corporateID ;
       ic:名称/ic:表記 ?corporateName ;
       ic:住所 ?key .
    ?key ic:表記 ?location .
  }
}
ORDER BY DESC(?score)

ご注意: 1トリプルが1ドキュメント(Lucene)に対応するシンプルなインデクシングであるため、空白ノードを多用するgBizINFOのデータモデルにおいては、複数の主語に対する複合的な全文検索が実用的でないケースがあります。例えば、法人名と所在地の表記に対してAND条件で全文検索しようとすると、それぞれの全文検索結果の主語の全組み合わせに対するパターンマッチを要するため、あっという間に現実的な時間でクエリが終わらなくなります。まず少数の結果に絞り込むことができる全文検索を実行した上で、それに対してFILTERするようなクエリに書き換えるなど、工夫が必要です。

名前付きグラフ一覧

• 法人基本情報: http://hojin-info.go.jp/graph/hojin
• 補助金情報: http://hojin-info.go.jp/graph/hojyokin
• 調達情報: http://hojin-info.go.jp/graph/chotatsu
• 表彰情報: http://hojin-info.go.jp/graph/hyosho
• 届出認定情報: http://hojin-info.go.jp/graph/todokede
• 特許情報: http://hojin-info.go.jp/graph/tokkyo
• 職場情報: http://hojin-info.go.jp/graph/shokuba
• 財務情報: http://hojin-info.go.jp/graph/zaimu
• 共通コード: http://hojin-info.go.jp/graph/commonCode

デフォルトグラフは、上記の名前付きグラフの和集合ですが、パフォーマンス上明示的に指定したほうが良いです。